Modify a text file: $/chase.pde

$/chase.pde

//// p1chase:  Mutt chases Bob. (+ animation)
String title=  "Mutt chases Bob";
String subtitle="(Sent back to kennel, if he catches Bob.)";
String news="";
String hint=  "Click to reposition Bob."
  + "\n 'h' sends Bob home; 'k' sends Mutt to kennel; 'r' resets all"
  + "\n     ('z' toggles headless)";
;
String author=  "B.A.Martin / dc_chase.pde";
String who = "Bob", dogname="Mutt";
boolean headless=true;
int frames=30;

float horizon;
float bobX, bobY;                // Position and speed of hero.
float bobXspeed, bobYspeed;
float fast=1;
float muttX, muttY;              // Position of dog.
float houseX=100, houseY=150, houseW=200, houseH=100;
float kennelX, kennelY;

color RED=color(255,0,0), GREEN=color(0,255,0), BLUE=color(0,0,255);
color YELLOW=color(255,255,0), CYAN=color(0,255,255), MAGENTA=color(255,0,255);
color PINK=color(255,200,220), BROWN=color(127,0,0), DARK=color(0,150,0);
color WHITE=color(255), BLACK=color(0), PALE=color(200);

//// SETUP:  Define screen size, set modes.
void setup()
{
  size( 800, 600 );
  smooth();
  frameRate(frames);
  //
  horizon=  height/3;
  houseY=   horizon-houseH;
  kennelX=  10;
  kennelY=  height-100;
  reset();
  hint += "\n +/- for faster/slower";
}
void reset() {
  bobHome();
  muttHome();
}
void bobHome() {
  // Start Bob at home.
  bobX=  houseX+5;                   // Bob starts in house door.
  bobY=  houseY+10;
  bobXspeed=  random( 2,7 );         // Random speeds.
  bobYspeed=  random( -3, +3 );
  fast=1;
  news= "Bob goes home!";
}
void muttHome() {
  muttX= kennelX+20; 
  muttY= kennelY+10;
  fast=1;
  news= "Mutt is sent back to the kennel!";
}

//// DRAW:  sky & sun plus creature
void draw()
{
  scene();
  action();
  show();
  messages();            // (Display the messages last.)
}

//// SCENE:  sky, sun, house.
void scene() {
  background( 200, 220, 250 );                // Blue sky
  fill( GREEN );
  rect( 0,horizon, width,height-horizon );    // Green grass
  house();
}
void house() {
  // Red house
  fill( RED );
  rect( houseX,houseY, houseW,houseH );              
  triangle( houseX,houseY, 
    houseX+houseW,houseY, 
    houseX+houseW/2,houseY-houseH/2 );
  // Brown door
  fill( BROWN );      // 
  rect( houseX+10,houseY+10, 50,houseH-10 );
  // Doghouse
  fill(WHITE);
  rect( kennelX,kennelY, 100,50 );
  fill(RED);
  text( "Kennel", kennelX+20,kennelY+20 );
  fill(BLACK);
  rect( kennelX+85,kennelY+10, 15,40 );
}

//// ACTION:  sun moves (then resets to random height)
void action() {
  // Move Bob & Mutt
  muttX=  muttX +  (bobX-muttX)  / 90;    // Mutt chases Bob
  muttY=  muttY  + (bobY- muttY) / 90;
  bobX=  bobX + bobXspeed*fast;      // Bob moves indpendently.
  bobY=  bobY + bobYspeed*fast;
  //// Bounce off the walls.
  if (bobX>width-30  || bobX<40) {
    bobXspeed = -bobXspeed;
    if (bobXspeed<0) news="Bob goes West";
    else news="Bob is heading East";
  }
  if (bobY>height-50-10 *bobXspeed || bobY<horizon/2- 10*bobYspeed) {
    bobYspeed = -bobYspeed;
    if (bobYspeed<0) news="Bob bounces UP";
    else news="Bob bounces down.";
  }
  // Send mutt to kennel.
  if ( dist(muttX,muttY, bobX, bobY) < 50) { 
    muttHome();
    news= "Mutt is sent back to the kennel!";
    bobY=horizon;          // And Bob goes up to the horizon.
  }
}

//// Show hero & dog.
void show() {
  hero();
  dog();
}
void hero() {
  // Draw creature.
  fill( BLUE );
  rect( bobX,bobY, 50, 80 );                 // Blue body
  fill( 200, 150, 100 );
  ellipse( bobX+25, bobY-20, 40,40 );       // Head on top
  fill( YELLOW );
  text( who, bobX+5, bobY +15 );              // Name on shirt
  // Eyes.
  fill( 255 );
  ellipse( bobX+15, bobY-25, 12, 12 );
  ellipse( bobX+35, bobY-25,  12,12 );
  fill( 0, 150, 0 );
  ellipse( bobX+15, bobY-23, 4, 4 );
  ellipse( bobX+35, bobY-23,  4,4 );
}
void dog() {
  fill( BROWN );
  rect( muttX,muttY, 70, 30 );                 // Brown dog
  // Animated legs.
  strokeWeight(3);
  float legX=muttX, legY=muttY+30, step=5;
  if (muttX%50 < 25 ) { step= -5; }
  for (int j=0; j<4; ++j) {
    legX += 15;
    line( legX,legY, legX+step,legY +20 );
  }
  strokeWeight(1);
  fill( YELLOW );
  text( dogname, muttX+15, muttY+15 );         // Name on body
  head();
}
void head() {
  if (headless) return;
  // Head -- faces East or West, depending on positions.
  float xHead, yHead;
  xHead= muttX<bobX ? muttX+50 : muttX-70+50;
  yHead= muttY-20;
  fill( 127,90,80 );
  rect( xHead,yHead, 40, 20 );
  // Eye.
  fill( 255 );
  ellipse( xHead+12, yHead+5, 12, 12 );
  fill( 0, 150, 0 );
  ellipse( xHead+12, yHead+3,  4,4 );
}

//// MESSAGES.
void messages() {
  fill(0);
  textSize(24);
  text( title, width/3, 20 );
  textSize(12);
  text( hint, width/2, horizon+20 );
  // Also display author & file name.
  text( author, 10, height-10 );
  fill(0);
  if (fast != 1) text( fast, width-100, 20 );
  fill(MAGENTA);
  textSize(18);
  text( news, 20, 40 );
}

//// EVENT HANDLERS ////
void mousePressed() {
  // Clixk to set position (x,y)
  bobX=  mouseX;
  bobY=  mouseY;
}
void keyPressed() {
  if (key == 'q') { exit(); }
  if (key == 'r') { reset(); }
  if (key == 'h' || key == 'b') { bobHome(); }
  if (key == 'k' || key == 'm') { muttHome(); }
  if (key == '+') { fast *= 1.25; }    // 25% speed up 
  if (key == 'z') { headless = ! headless; }
  //
  if (key == 'f') { frameRate(5); }
  if (key == ' ') { frameRate(frames); }
}