Modify a text file: $/p1c.java

$/p1c.java

String title=  "Project 1c";
String author=  "B.A.Martin -- CST 112"; 
String heroName=  "George";

float georgeX, georgeY;
float look;
float muttX, muttY, tickX, tickY;
float sunX, sunY;
float horizon;

boolean debug=false;

//// SETUP: screen size
void setup() {
  size( 640, 480 );
  horizon=  height/4;
  sunX=  -50;
  sunY=  horizon - 50;
}

//// Next frame.
void draw() {
  scene();
  action();
  show();
  credits();
}

//// Draw the scene.
void scene() {
  background( 100, 220, 250 );
  fill( 200, 250, 200 );
  rectMode( CORNERS );
  rect( 0,horizon, width, height ); 
  
  // Sun.
  fill( 255,255,0 );
  noStroke();
  ellipse( (float) sunX, sunY, 30,30 );
  sunX=  (sunX + 1) % (width+100);
  sunY=  horizon-20  -  0.75 * horizon * sin( PI * sunX/width );
  stroke(0);

// House
  rectMode( CORNER );
  fill(255,0,0);
  rect( 120, horizon-50, 60, 50 );
  triangle( 120,horizon-50, 180,horizon-50, 150,horizon-70 );
  fill(0);
  rect( 125, horizon-35, 10, 10 );
  rect( 165, horizon-35, 10, 10 );
  rect( 142, horizon-35, 16, 33 );
  
  // Trees.
  fill( 150, 0, 0 );
  rectMode( CORNER );
  rect( 200, horizon, 20, -60 );
  rect( 300, horizon, 25, -70 );
  rect( 400, horizon, 15, -50 );

noStroke();
  fill( 0, 120, 0 );
  ellipse( 210, horizon-70, 35, 35 );
  fill( 50, 180, 50 );
  ellipse( 312, horizon-85, 55, 40 );
  fill( 50, 250, 100 );
  ellipse( 407, horizon-45, 30, 30 );
  stroke(0);
}

//// Move the actors.
void action() {
  // Move George
  //--  georgeX=  mouseX;
  //--  georgeY=  mouseY;
  georgeX=  georgeX + (mouseX-georgeX) / 20;    // Chase the mouse.
  georgeY=  georgeY + (mouseY-georgeY) / 40;

if (georgeY < horizon) georgeY=  horizon;
  
  // Look in direction of motion.
  look=0;
  if (mouseX>pmouseX) look = 2;
  if (mouseX<pmouseX) look = -2;

// Move the dog
  muttX=  muttX + (georgeX-muttX) / 90;            // Dog chases hero.
  muttY=  muttY + (georgeY-muttY) / 150;

// Move the bug
  tickX=  tickX + (sunX-tickX) / 90;            // bug follows sun & mutt.
  tickY=  tickY + (muttY-tickY) / 90;

// DEBUGGING
  if ( ! debug) return;
  fill(0);
  text( (int) georgeX +","+ (int) georgeY, georgeX,georgeY+50 );
  text( (int) muttX +","+ (int) muttY, muttX,muttY+30 );
  text( (int) tickX +","+ (int) tickY, tickX,tickY+30 );

}

//// Display the actors.
void show() {

// George, the hero.
  fill( 255, 150, 0 );
  rectMode( CENTER );
  rect( georgeX, georgeY, 50, 80 );        // Body.
  fill( 220, 150, 150 );
  ellipse( georgeX, georgeY-55, 30, 30 );  // Head.
  fill( 255, 255, 0 );
  triangle( georgeX-15, georgeY-65, georgeX+15, georgeY-65, georgeX, georgeY-80 );      // Hat
  
  // Eyes:
  fill( 255 );
  ellipse( georgeX-8, georgeY-60, 10, 10 );  // Eyes
  ellipse( georgeX+8, georgeY-60, 10, 10 );  // Eyes
  fill( 0,0,255 );
  ellipse( georgeX-8+look, georgeY-60, 4, 4 );  // Eyeball
  ellipse( georgeX+8+look, georgeY-60, 4, 4 );

fill( 255, 0, 0 );                        // Name.  
  text( heroName, georgeX-20, georgeY-20 );

// mutt
  fill( 100, 50, 0 ); 
  rect( muttX, muttY, 60, 30 );
  
  float muttFace=40;
  if (muttX>georgeX) muttFace=  -40;  
  rect( muttX + muttFace, muttY-20, 30, 20 );  
  fill(255);
  ellipse( muttX + muttFace*1.2, muttY-25, 10, 10 );

// Bug
  fill( 150 );
  float xx=  random( 6 );
  ellipse( tickX, tickY, 20, 10 );
  line( tickX-10, tickY+4, tickX-12+xx, tickY+8 );
  line( tickX-5, tickY+4, tickX-7+xx, tickY+8 );
  line( tickX+5, tickY+4, tickX+3+xx, tickY+8 );
  line( tickX+10, tickY+4, tickX+10+xx, tickY+8 );
}

//// Put some text on the screen..
void credits() {
  fill( 0 );
  text( title, width/3, 20 );
  text( author, 20, height-20 );
  fill(150);
  text( "Click mouse to send "+ heroName +" home!", width/2, height-60 );
  text( "Press d key for debugging", width/2, height-40 );
}

//// EVENT HANDLERS ////
void keyPressed() {
  if (key == 'd') debug = ! debug;    // Toggle the debug flag.
  else println( "Unexpected keyPressed:  " + key );
}
void mousePressed() {
  georgeX=  120;        // Teleport to the house.
  georgeY=  horizon;
}